Jw_cad 相談室−その2 New

 Jw_cad についての相談の場としてお使いください
情報の交換には Jw_cad 情報交換室 をご利用ください
なお、情報交換室と相談室の両方に同じ内容を投稿するのはご遠慮ください

2009年9月以前の発言過去ログのページからご覧ください。

それ以降の過去ログは消失しています。
申し訳ありませんが、復活の予定はありません。


  新規投稿 ┃ツリー表示 ┃スレッド表示 ┃一覧表示 ┃トピック表示 ┃番号順表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
87 / 1498     ←次へ | 前へ→

Re:画面移動を矢印以外のキーボードで行いたい。
 LA  - 17/3/30(木) 6:04 -
こんにちは
R.Nさん いっちさん ご試用ありがとうございます。


wasd.ahk 改造版です。
動作がなかなか安定しなくて時間がたち過ぎたため公開するか悩んだのですが、いっちさんの別スレでの質問を見て、やっぱり公開することにします。

大変遅くなってしまい、申し訳ありませんが、
もしよろしければ、使ってやって下さい。


基本部分をリマップ->ホットキーにしましたので、記載以外の修飾キーも同時押した場合には反応しなくなりました。
これにより、ShiftやCtrlキー同時押しとの住み分けが可能になります。

あと、基本設定(2)でオフセット〜On の場合を想定していませんでしたので、どちらでも動作出来るようにし、自動検出も付けました。


;JWW用WASDキー 要AutoHotKey Unicode版32/64bit + このスクリプトをUTF-8(BOM有)で保存
#usehook
SetTitleMatchMode,RegEx
mode=0 ;1:矢印キー〜がOn 2:オフセット〜がOn 0:自動検出 いらない場合は1か2に
jwwDraw=AfxFrameOrView120s1 ;JWWv8の場合 v7:90 v6:42 に数字を変更
WM_COMMAND := 0x111
btn=キャンセル

;mode自動検出
If mode=0
IfWinExist, ahk_exe Jw_win.exe ;何故か大文字小文字区別するっぽい
{
WinActivate
WinGetTitle, title

;基本設定
If title=jw_win ;既に基本設定がアクテイブか
btn=OK ;既にアクテイブの場合は設定内容を反映させる
else {
PostMessage, %WM_COMMAND%, 32891 ;基本設定
;Send, !ss ;だと文字コマンドの時安定しなかった
WinWaitActive, ^jw_win$
}

SetTabNum(2) ;タブを一般(2)(=2)に
ControlGet, ck, Checked,, オフセット・複写・移動・パラメトリック変形のXY数値入力のときに矢印キーで確定
PushBtnUntilWinExist(btn) ;基本設定ダイアログ(=LastFoundWindow)を閉じる
mode:=ChMode(ck? 2:1) ;オフセット〜 矢印キー〜 両方Offの場合については考慮しない
ControlFocus, %jwwDraw%
} else
mode:=ChMode(1) ;JWWが開いてない場合は強制的に1

Return


;+:Shift ^:Ctrl !:Alt #:Win <:左側のキー >:右側のキー
#If IsJwwDraw() and mode=1 ;この場合は矢印で移動 Ctrl+矢印でオフセット
w::Send,% GetScrLk("+") "{Up}"
s::Send,% GetScrLk("+") "{Down}"
a::Send,% GetScrLk("+") "{Left}"
d::Send,% GetScrLk("+") "{Right}"

#If IsJwwDraw() and mode=2 ;この場合はCtrl+矢印で移動 矢印でオフセット
w::Send,% "^" GetScrLk("+") "{Up}"
s::Send,% "^" GetScrLk("+") "{Down}"
a::Send,% "^" GetScrLk("+") "{Left}"
d::Send,% "^" GetScrLk("+") "{Right}"
;Shift付の小移動はAltやWin代用では動作が安定しなかったのでScrollLockで代用
;Ctrl+s や 外変直接起動 とか使いたいので Ctrl同時押しないですむように

#If IsJwwDraw() ;検出ミスした時用
>^1::mode:=ChMode(1)
>^2::mode:=ChMode(2)
;右Ctrl+フルキーの1,2 のみ


IsJwwDraw() ;JWWのメインウインドウがアクティブかの判定
{
;WinActive("- jw_win$ || ^◆◆◆ブロック図形") はうまく動作しなかった
IfWinNotActive, ahk_exe Jw_win.exe
Return False
WinGetClass, class
If class=#32770
Return False
Return true
}


ChMode(md)
{
If md=2
ToolTip, オフセット・複写・移動・パラメトリック変形のXY数値入力のときに矢印キーで確定
Else {
md=1
ToolTip, 矢印キーで画面移動 PageUp・PageDownで画面拡大・縮小、Homeで全体表示にする
}
Sleep, 1000
ToolTip
Return md
}


SetTabNum(num,win="",w=50) ;tabをnumにする
{
ControlGet, tab, Tab,,SysTabControl321,%win%
If tab <= % num
Control, TabRight,% num-tab , SysTabControl321,%win% ;マイナス値はNGらしい
Else
Control, TabLeft,% tab-num , SysTabControl321,%win%
loop{
Sleep, w
ControlGet, tab, Tab,, SysTabControl321,%win%
If tab=%num%
break
}}


PushBtnUntilWinExist(btn="OK",win="",w=50) ;winが無くなるまでbtnを連打
{loop {
Controlclick, %btn%,%win%,,L,,NA
IfWinNotExist,%win%
break
sleep, %w%
}}


GetScrLk(c)
{ Return GetKeyState("ScrollLock","T")? c:""
;Capsか迷った
}


GetTab()
{ ControlGet, tab, Tab,, SysTabControl321
Return tab
}


引用なし

パスワード


<Mozilla/5.0 (Windows NT 10.0; WOW64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/56.0.2924.87 Safari/537.36 Sleipnir...@ntngno055002.ngno.nt.ngn.ppp.infoweb.ne.jp>
・ツリー全体表示

画面移動を矢印以外のキーボードで行いたい。 Naka 17/3/11(土) 9:32
Re:画面移動を矢印以外のキーボードで行いたい。 Fu〜 17/3/11(土) 22:05
Re:画面移動を矢印以外のキーボードで行いたい。 くにば 17/3/11(土) 23:06
Re:画面移動を矢印以外のキーボードで行いたい。 mirror 17/3/22(水) 20:01
Re:画面移動を矢印以外のキーボードで行いたい。 LA 17/3/12(日) 16:02
Re:画面移動を矢印以外のキーボードで行いたい。 R.N 17/3/23(木) 21:20
Re:画面移動を矢印以外のキーボードで行いたい。 いっち 17/3/25(土) 8:35
Re:画面移動を矢印以外のキーボードで行いたい。 R.N 17/3/25(土) 19:26
Re:画面移動を矢印以外のキーボードで行いたい。 いっち 17/3/25(土) 23:36
Re:画面移動を矢印以外のキーボードで行いたい。 R.N 17/3/26(日) 6:16
Re:画面移動を矢印以外のキーボードで行いたい。 mirror 17/3/26(日) 10:01
Re:画面移動を矢印以外のキーボードで行いたい。 いっち 17/3/26(日) 11:19
Re:画面移動を矢印以外のキーボードで行いたい。 mirror 17/3/26(日) 12:17
Re:画面移動を矢印以外のキーボードで行いたい。 いっち 17/3/26(日) 15:01
Re:画面移動を矢印以外のキーボードで行いたい。 いっち 17/3/26(日) 15:05
Re:画面移動を矢印以外のキーボードで行いたい。 LA 17/3/30(木) 6:04
Re:画面移動を矢印以外のキーボードで行いたい。 いっち 17/3/30(木) 23:37
これは楽しい マチャプチャレ 17/3/31(金) 7:14
参考になりました マチャプチャレ 17/4/3(月) 14:15
Re:画面移動を矢印以外のキーボードで行いたい。 いっち 17/4/8(土) 7:54
Re:画面移動を矢印以外のキーボードで行いたい。 mirror 17/4/8(土) 9:57
Re:画面移動を矢印以外のキーボードで行いたい。 いっち 17/4/8(土) 11:35
Jw_cad標準ではなくExmenuで設定した場合 いっち 17/4/10(月) 12:06

87 / 1498     ←次へ | 前へ→
  新規投稿 ┃ツリー表示 ┃スレッド表示 ┃一覧表示 ┃トピック表示 ┃番号順表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
 367388
ページ:  ┃  記事番号:  

C-BOARD Moyuku v1.03b3
Jw_cad Copyright (C)1997-2016 Jiro Shimizu & Yoshifumi Tanaka